تابع LET اکسل - نامی برای یک محاسبه

تابع LET در نسخه اکسل ۲۰۲۱ اضافه شده است. اگر شما با مفاهیم برنامه نویسی آشنا باشید، روش کار این تابع بسیار برای شما منطقی و ساده است و در غیر اینصورت به نظرتان شاید کمی عجیب برسد. اجازه دهید با یک مثال بسیار ساده و ابتدایی به شما کارکرد LET را آموزش دهم.

مثال ۱) تابع LET

دختر شما (باران) روزی به میوه فروشی می‌روید و می‌بینید که انار‌های خیلی خوبی دارد 🤩 و فرض کنید که ۲۰ عدد انار می‌خرد. از طرف دیگر آبتین (پسر ❤ شما) هم می‌داند که انار دوست دارید و برای شما ۳۰ عدد انار می‌خرید. اگر بخواهم خرید باران و آبتین را به زبان کامپیوتری (یا ریاضی) بنویسیم، چیزی شبیه زیر را خواهیم داشت:

anar_baran = 20
anar_abtin = 30

یعنی دو «نام» داریم. یکی به نام anar_baran که مقدارش عدد ۲۰ است و دیگری به نام abar_abtin که مقدارش عدد ۳۰ است.

و وقتی به خانه می‌رسید جمع کل انارهای شما به شکل ریاضی با استفاده از این «نام‌ها» اینگونه خواهد شد:

anar_baran + anar_abtin

حال همین کار را می‌توانیم در اکسل با تابع LET‌ انجام دهیم. برای اینکار کافی است که در اکسل ۲۰۲۱ فرمول زیر را بنویسیم:

=LET( anar_baran, 20, anar_abtin, 30, anar_baran + anar_abtin)

شرح فرمول LET در مثال قبلی

اجازه دهید آخرین فرمول را قدم به قدم با هم بنویسیم و من به شما توضیح دهیم:

قدم ۱) 

=LET( anar_baran

با تابع LET یک «نام» anar_baran را تعریف کرده‌ایم. این نام می‌تواند هر واژه‌ای باشد. 

قدم ۲)

می‌خواهیم که anar_baran را مقدار دهی کنیم. این کار را اینگونه انجام می‌دهیم:

=LET( anar_baran, 20

به anar_baran در دنیای کامپیوتر «متغیر» می‌گویند یعنی می‌توانیم هر چیزی که می‌خواهیم را در آن ذخیره کنیم. 

قدم ۳ و ۴)

می‌خواهیم یک «متغیر» دیگر به نام anar_abtin تعریف کنیم و مقدار آن را عدد 30 قرار دهیم. فرمول را به صورت زیر تکمیل می‌کنیم:

=LET( anar_baran, 20, anar_abtin, 30

از الگوی بالا می‌بینید که می‌توانیم با LET چندین متغیر (یا نام) را تعریف کنیم و به آن‌ها مقدار بدهیم. کافی است که نام متغیر را بنویسیم و سپس مقدار آن را مشخص کنیم.

قدم ۵) 

حال می‌توانیم از اکسل بخواهیم که هر محاسبه‌ای را روی این متغیرها انجام دهد. برای این کار کافی است که محاسبه را به عنوان آخرین ورودی تابع LET مانند زیر بنویسیم:

=LET( anar_baran, 20, anar_abtin, 30, anar_baran + anar_abtin)

همین که ENTER را بزنیم، اکسل برای شما نتیجه محاسبه یعنی عدد 50 را نمایش خواهد داد.

مثال ۲) تابع LET اکسل

 با تابع LET سه متغیر به نام‌های x و y و z تعریف کنید و به ترتیب اعداد ۱۰ و ۲۰ و ۳۰ را در آنها ذخیره کنید و سپس حاصل ضرب آنها محاسبه کنید؟

نکته) ما در اکسل می‌توانیم با زدن کلید Alt + Enter یک فرمول را در چند سطر بنویسیم تا خواناتر شود.

=LET(x, 10,
     y, 20,
     z, 30,
     x * y * z)

توجه) همانطور که می‌بینید نام متغیر و مقدارش با هم یک زوج را می‌سازند.

مثال ۳)

 مبالغ فروش شرکت در ستون B اکسل وارد شده است و مبالغ هزینه‌ها در ستون C. فرمولی بنویسید که درآمد (جمع فروش‌ها منهای جمع هزینه‌ها ) را محاسبه کند.

=LET( sales, SUM(B:B),
      cost, SUM(C:C),
      sales - cost)

شرح فرمول) ما در متغیر sales می‌توانیم هر چیزی را ذخیره کنیم و جمع فروش‌ها را در آن ذخیره کرده‌ایم و در سطر دوم یک متغیر به نام cost‌ را تعریف کرده‌ایم و در آن جمع هزینه‌ها را ذخیره کرده‌ایم و سپس مقدار sales - cost‌ را محاسبه کرده‌ایم.

توجه) یکی از اهداف استفاده از تابع LET نوشتن فرمول‌های خواناتر است. دقیقا مانند چیزی که در این مثال دیدیم.

در واقع شما می‌توانستید همین کار را به سادگی با فرمول  =SUM(B:B) - SUM(C:C) انجام دهید. اما این فرمول هیچ نشانه‌ای ندارد که شما چه قصدی را داشته‌اید و آن را مقایسه کنید با فرمولی که بسیار خواناتر با LET‌ نوشته شده است.

حذف محاسبات تکراری با تابع LET اکسل

در مثال‌های قبلی با نحوه استفاده از تابع LET آشنا شدیم اما باید بدانید که:

کاربرد اصلی و مهم تابع LET حذف محاسبات تکراری در یک فرمول اکسل است تا کارآیی و سرعت محاسبات بالاتر رود.

تا قبل از بوجود آمدن تابع LET، ما مجبور بودیم که گاهی یک محاسبه را در ۱ فرمول چندین بار انجام دهیم. 

مثال ۴)

فرض کنید که من می‌خواستم بر اساس جمع فروش که در ستون B اکسل است، تصمیم بگیریم که چند درصد تخفیف دهیم. اگر فروش بالای ۱۰۰۰ بود ٪۱۰ و اگر بالای ۵۰۰ بود آنگاه٪۵ و در غیر اینصورت ٪۰ تخفیف را منظور کنم.

همانطور که در فرمول زیر می‌بینید SUM(B:B) ، دو بار تکرار شده است و اکسل را مجبوریم کرده‌ایم که در یک فرمول ۲ بار جمع ستون B را محاسبه کند:

=IF( SUM(B:B) > 1000, 10%, IF( SUM(B:B) > 500, 5%, 0) )

اکنون که تابع LET را داریم به سادگی می‌توانیم جمع فروش را فقط ۱ بار محاسبه کنیم و  در یک متغیری به نام sales (یا هر نام دلخواه دیگری) ذخیره کنیم و بر اساس مقدار این متغیر فرمول زیر را بنویسیم و دیگر اکسل مجبور نیست که جمع را ۲ بار محاسبه کند:

=LET(
      sales, SUM(B:B),
      IF( sales > 1000, 10%, IF( sales > 500, 5%, 0) ) )

نکته) برای حل این مثال و جلوگیری از محاسبات تکراری ما می‌توانیم از VLOOKUP و یا تابع SWITCH هم استفاده کنیم و در اینجا عامدن ذکر نشده است تا تمرکز شما فقط بر روی تابع LET باقی بماند.